Can someone explain how the below formula to transpose all rows to one column works?

[antman2988]

Hello,

I have used this formula: **=INDEX( MyData,INT((ROW()-ROW( $Z$1 ))/COLUMNS( MyData ))+1,MOD(ROW()-ROW( $Z$1 ),COLUMNS( MyData ))+1)** to transpose all of my rows of data into one column. Unfortunately, I can't entirely wrap my head around how it works.

Would someone be willing to explain it to me? Any assistance is appreciated.

Thanks,
Anthony Smith

 

[Eric W]

Break it into parts. I assume you're putting the formula in Z1 and dragging down.

	Z	AA	AB	AC
1	5	0	1	1
2	3	1	1	2
3	1	2	1	3
4	0	3	1	4
5	10	4	1	5
6	0	5	1	6
7	7	6	1	7
8	10	7	1	8
9	1	8	2	1
10	7	9	2	2
11	3	10	2	3
12	3	11	2	4
13	5	12	2	5
14	9	13	2	6
15	1	14	2	7
16	8	15	2	8
17	8	16	3	1
18	1	17	3	2
19	2	18	3	3
20	6	19	3	4
21	1	20	3	5
22	8	21	3	6
23	7	22	3	7
24	2	23	3	8

<colgroup><col style="width: 25pxpx"><col><col><col><col></colgroup><thead>
</thead><tbody>
</tbody>

Sheet1​

Worksheet Formulas Cell Formula Z1 =INDEX( MyData,INT((ROW()-ROW( $Z$1 ))/COLUMNS( MyData ))+1,MOD(ROW()-ROW( $Z$1 ),COLUMNS( MyData ))+1) AA1 =ROW()-ROW($Z$1) AB1 =INT((ROW()-ROW( $Z$1 ))/COLUMNS( MyData ))+1 AC1 =MOD(ROW()-ROW( $Z$1 ),COLUMNS( MyData ))+1 <thead> </thead><tbody> </tbody>

<tbody>
</tbody>

Workbook Defined Names Name Refers To MyData =Sheet1!$F$3:$M$10 <thead> </thead><tbody> </tbody>

<tbody>
</tbody>

Put the AA1 formula in and drag down. As you can see, it just counts up from 0. Subtracting the starting row from the current row does that.

Put the AB1 formula in and drag down. When you divide the number in AA by the number of columns in your table (my sample table has 8), and drop the remainder (INT), you get a counter that only increments by 1 for every row in your table.

Put the AC1 formula in and drag down. The MOD function is equivalent to dividing by the number of columns and taking the remainder, then we add 1. So this pattern repeats 1-8 over and over.

Then finally INDEX uses the first number (AB) as an index into your table for the row, and uses the second number (AC) as an index for the column.

Hope this helps.