Count values from one column

[dyheids]

Can anyone help me count date from one column, duplicate values as one within a date. for example

Column 1 Column 2
3/1/18 eva
3/1/18 dan
3/2/18 eva
3/2/18 eva


If counted it should be 3 names only.
Thank you.....

 

[rlv01]

Here is one way:

Sub CountUniqueNameDateCombos()    Dim Rng As Range, R As Range
    Dim n As Long
    Dim SD As Object
    Dim KeyStr As String, RefStr As String

    Set SD = CreateObject("Scripting.dictionary")
    Set Rng = Range("A1", Range("A" & Rows.Count).End(xlUp))    'Assume data is columns A & B (Date & Name)

    RefStr = ""
    For Each R In Rng
        KeyStr = R.Value & " " & R.Offset(0, 1).Value  'Search Key stored in dictionary
        If Not SD.exists(KeyStr) Then    'Unique key value, not already in the dictionary
            SD.Add KeyStr, RefStr
        End If
    Next R


    MsgBox "There are " & SD.Count & " unique Date/Name combinations"


    'Put the unique values in column C. or Modify to put them where you like
    With Range("C1")
        For n = 0 To SD.Count - 1
            .Offset(n).Value = SD.keys()(n)
        Next n
    End With

    'Or else split the data and the name and put them in columns D & E. Modify to suit your requirements
    With Range("D1")
        For n = 0 To SD.Count - 1
            .Offset(n).Value = Split(SD.keys()(n), " ")(0)
            .Offset(n, 1).Value = Split(SD.keys()(n), " ")(1)
        Next n
    End With

    Set SD = Nothing
End Sub

 

[dyheids]

Is this possible if I have multiple sheets

i.e.

Sheet 1 gets its values from sheet 2..

 

[rlv01]

Yes it is possible. The specifics would depend on how you had the data organized on sheet 1 and sheet 2