Excel Macro Export to PDF

[bdenn]

Hello,
I am using the following macro to save the current selected sheet as a PDF. When I go and edit the path I want it to save to it fails the macro and I think it has something to do with: ("userprofile") But if I create a folder on the desktop: \Holding\ it works fine.

I would like to be able to change this to the following path: C:\North\Transmission\Transmission Systems Logging\PDF Export

Also, I was wondering is there a way to adjust the macro to save all sheets to there own PDF files still using the sheet name and adding the current date at the end? This would make it so I would not need to click each sheet and run the macro, There is about 15 Sheets.

Thank You,
Bdenn

Sub Export_PDF()
    ' Saves active sheet as PDF file.


    Dim FName As String
    
    FName = Environ("userprofile") & "\Desktop\Holding\" & ActiveSheet.Name & " " & _
        Format(Now(), "mm-dd-yyyy") & ".pdf"
    
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FName, _
        Quality:=xlQualityStandard, IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, OpenAfterPublish:=False
End Sub

 

[Yongle]

To save all the worksheets to separate files, use this method

Sub Export_PDF()
    ' Saves active sheet as PDF file.

    Dim FName As String, ws As Worksheet
    For Each ws In ThisWorkbook.Worksheets
        
        FName = Environ("userprofile") & "\Desktop\Holding\" & ws.Name & " " & Format(Now(), "mm-dd-yyyy") & ".pdf"

        ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FName
    Next ws
End Sub

 

[Yongle]

I am using the following macro to save the current selected sheet as a PDF. When I go and edit the path I want it to save to it fails the macro and I think it has something to do with: ("userprofile") But if I create a folder on the desktop: \Holding\ it works fine.

I would like to be able to change this to the following path: C:\North\Transmission\Transmission Systems Logging\PDF Export

Are you saying that if folder does not already exist then save to the other path ?
- here is a method to do that, using a function to test the existence of the folder

Sub Export_PDF()

    Dim FldrName As String, FName As String, ws As Worksheet
    Const DefaultFldr = "C:\North\Transmission\Transmission Systems Logging\PDF Export"
    FldrName = Environ("userprofile") & "\Desktop\Holding"
'if folder does not exist then revert to default folder
    If FldrExists(FldrName) = False Then FldrName = DefaultFldr
   
    For Each ws In ThisWorkbook.Worksheets   
         FName = FldrName & "\" & ws.Name & " " & Format(Now(), "mm-dd-yyyy") & ".pdf"
        ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FName
    Next ws
   
End Sub

Function FldrExists(ByVal fldr As String) As Boolean
    With CreateObject("Scripting.FileSystemObject")
        FldrExists = .FolderExists(fldr)
    End With
End Function

 

[Yongle]

If, on the other hand, you want to create the folder if it does not already exist

Sub Export_PDF()

    Dim FldrName As String, FName As String, ws As Worksheet
    FldrName = Environ("userprofile") & "\Desktop\Holding"

'if folder does not exist then create it
    If FldrExists(FldrName) = False Then MkDir FldrName

'etc   

End Sub