Finding Current AND Longest Winning Streak based on TWO Criteria

[SnKeaK]

Status	Bookmaker	Rating
Win	Nitrogen Sports	Pick of the Day
Loss	Nitrogen Sports	Regular
Win	TRP Special	Pick of the Day
Loss	TRP Special	Pick of the Night
Win	TRP Special	Pick of the Day
Win	TRP Special	Pick of the Night

<tbody>
</tbody>

Alright, So I am trying to find the current Win Streak for "Pick of the Day". n this example it'd be 3 because Column A = Win AND Column C = Pick of the Day. However if you look for the current streak of Pick of the Night, it'd only be 1. I need formula to find Current and another formula to find Longest streak given two criteria...Criteria being Column A = Win and Column C = Pick of the Day(for this example)

I figure I'd have to use MAX and Frequency combo but I can't figure out how to incorporate them based on if two criteria are met. Thanks.

 

[Marcelo Branco]

I'm afraid i misunderstood what you are looking for. Does the current streak begin in A1?

M.

 

[SnKeaK]

Base on your example yes. For Pick of the Day the Current Streak begins A1, because it hasn't lost. For Pick of the Night, it'd be A13. Now let's say we change A11 to Win...The Pick of the Night Current streak would have started on A8 and the current streak would be 5

 

[Marcelo Branco]

See if this is ok

	A​	B​	C​	D​	E​	F​	G​	H​	I​	J​
1​	Win​	Nitrogen Sports​	Pick of the Day​		Criteria1​	Criteria2​	Max Streak​	DataLastRow​	LastRow<>Criteria​	Current Streak​
2​	Loss​	Nitrogen Sports​	Regular​		Win​	Pick of the Night​	3​	13​	11​	1​
3​	Win​	TRP Special​	Pick of the Day​
4​	Loss​	TRP Special​	Pick of the Night​
5​	Win​	TRP Special​	Pick of the Day​
6​	Win​	TRP Special​	Pick of the Night​
7​	Loss​	TRP Special​	Pick of the Night​
8​	Win​	TRP Special​	Pick of the Night​
9​	Win​	TRP Special​	Pick of the Night​
10​	Win​	TRP Special​	Pick of the Night​
11​	Loss​	TRP Special​	Pick of the Night​
12​	Win​	TRP Special​	Pick of the Day​
13​	Win​	TRP Special​	Pick of the Night​
14​

<tbody>
</tbody>

Criteria in E2:F2

Max streak
Array formula in G2
=MAX(FREQUENCY(IF(C1:C100=F2,IF(A1:A100=E2,ROW(A1:A100))),IF(C1:C100=F2,IF(A1:A100<>E2,ROW(A1:A100)))))
Ctrl+Shift+Enter

Formula in H2 (last row with data)
=MATCH(REPT("z",255),B:B)

Formula in I2 (last row: column C=F2 and column A=Loss)
=IFERROR(LOOKUP(2,1/((C1:C100=F2)*(A1:A100<>E2)*(A1:A100<>"")),ROW(B1:B100)),1)

Current streak
=COUNTIFS(INDEX(A:A,H2):INDEX(A:A,I2),E2,INDEX(C:C,H2):INDEX(C:C,I2),F2)

M.

 

[SnKeaK]

That did it! Thank you so much. I really appreciate your time on this.