formula require...

[VBABEGINER]

hi all,

I need formula, where lookup values are in two different columns, and with combination of these 2 values I want to find an answer....

Column A	Column B	Column C	Column D	Column E
E	L	p	q	r
30	L1	10	40	60
31	L2	20	50	70
31	L1	30	60	80
Value to find		Answer Require..
31	L1	80

<colgroup><col><col><col><col><col></colgroup><tbody>
</tbody>

I use this formula, but these is something wrong..

=VLOOKUP(AND(A4,B4),A2:E4,3,FALSE)

 

[Scott T]

If you are always looking in column E

Excel 2010

	A	B	C	D	E
1	E	L	p	q	r
2	30	L1	10	40	60
3	31	L2	20	50	70
4	31	L1	30	60	80
5
6	value o find		answer
7	31	l1	80

<colgroup><col><col><col><col><col><col></colgroup><thead>
</thead><tbody>
</tbody>

Sheet4​

Array Formulas Cell Formula C7 {=INDEX(E2:E4,MATCH(A7&B7,A2:A4&B2:B4,0))} <thead> </thead><tbody> </tbody> Entered with Ctrl+Shift+Enter. If entered correctly, Excel will surround with curly braces {}. Note: Do not try and enter the {} manually yourself

<tbody>
</tbody>

 

[snjpverma]

Is there a way to do this without using array? Just curious to know alternative ways of doing this.

 

[bosco_yip]

Try,

=VLOOKUP(A4&B4,IF({1,0},INDEX(A1:A4&B1:B4,0),E1:E4),2,FALSE)

Regards
Bosco

 

[Scott T]

Is there a way to do this without using array? Just curious to know alternative ways of doing this.

You could use a helper column to concatenate the two columns to avoid and array formula.

Excel 2010
	A	B	C	D	E	F
1	E	L	p	q	r	helper
2	30	L1	10	40	60	30L1
3	31	L2	20	50	70	31L2
4	31	L1	30	60	80	31L1
5
6	value o find		answer
7	31	l1	80
Sheet4

Cell Formulas
Range	Formula
F2	=A2&B2
F3	=A3&B3
F4	=A4&B4
C7	=INDEX(E2:E4,MATCH(A7&B7,F2:F4,0))

 

[bosco_yip]

Or, using post #2 table, in C7 :

=SUMIFS(E2:E4,A2:A4,A7,B2:B4,B7)

Regards
Bosco

 

[VBABEGINER]

I really dont understand how this works..?
Simple enter..nothing giving..
ctr shft enter ... giving me answer...I understand that this is array technology...but how...

If you are always looking in column E

Excel 2010

	A	B	C	D	E
1	E	L	p	q	r
2	30	L1	10	40	60
3	31	L2	20	50	70
4	31	L1	30	60	80
5
6	value o find		answer
7	31	l1	80

<tbody>
</tbody>

Sheet4​

Array Formulas Cell Formula C7 {=INDEX(E2:E4,MATCH(A7&B7,A2:A4&B2:B4,0))} <tbody> </tbody> Entered with Ctrl+Shift+Enter. If entered correctly, Excel will surround with curly braces {}. Note: Do not try and enter the {} manually yourself

<tbody>
</tbody>

 

[VBABEGINER]

I really dont understand, how this too work???

it giving my answer..but worked...how..?

some Questions..

1. what IF is doing here..
2. Why column index taken 2, wherein it should be 3?

Try,

=VLOOKUP(A4&B4,IF({1,0},INDEX(A1:A4&B1:B4,0),E1:E4),2,FALSE)

Regards
Bosco

 

[VBABEGINER]

Can you please explain why it require, ctr shft entr to press..

If you are always looking in column E

 

[bosco_yip]

I really dont understand, how this too work???

it giving my answer..but worked...how..?

some Questions..

1. what IF is doing here..
2. Why column index taken 2, wherein it should be 3?

=VLOOKUP(A4&B4,IF({1,0},INDEX(A2:A4&B2:B4,0),E2:E4),2,FALSE)

>>

=VLOOKUP("31L1",IF({1,0},{"30L1";"31L2";"31L1"},{60;70;80}),2,FALSE)

>>

=VLOOKUP("31L1",{"30L1",60;"31L2",70;"31L1",80},2,FALSE)

>>

=80

Regards
Bosco