How to count the number of wednesdays in the next month given the date of the last wednesday of the previous month

[aletheasim96]

Hello everyone! Okay im super new to excel vba so I apologise if my question is really basic:P I've been asked to automate the sheet below but have no idea how to go about it. So the data values in the table are linked to a PHD system that generates the data using the dates at the top of each column. So what i am supposed to do is to come up with a button that can generate the dates of the next 4 or 5 wednesdays in the next month, depending on exactly how many wednesdays fall in the next month, given the date of the last wednessday of the previous month, in this case 28 Feb. So the desired end result of running the code would be to add the next 4 or 5 wednesdays to the columns next to the last entry(28 Feb in this case) and to drag the formulas from the previous data columns to generate the results for these new columns. Could anyone give me advice on how to do this? Any help is much appreciated!!!

03-Jan-2018 8:48:00PM	10-Jan-2018 8:48:00PM	17-Jan-2018 8:48:00PM	24-Jan-2018 8:48:00PM	31-Jan-2018 8:48:00PM	07-Feb-2018 8:48:00PM	14-Feb-2018 8:48:00PM	21-Feb-2018 8:48:00PM	28-Feb-2018 8:48:00PM
2654	254	254	24	52	687	76	67	67
423	45	3454	2452	52	5	25	86	78
245	2452	54	42	4	42	87	52	76
42	245	254	4	542252	45	5225	78	86
452	452	424	25	25	25	525	89	785
45	45	24	4	54	8	67	67	54

<tbody>
</tbody>

Thank you!!!!

 

[Scott T]

Try this
I assume the dates are in row 1 and they are excel dates not text. I find the last row used based on column A. Change to a column that will always have data. I assume the data starts in row 2

Sub popwed()

Dim lc As Long
Dim lr As Long
Dim lastwed As Date
Dim lmonth As Long
Dim nmonth As Long


lc = Cells(1, Columns.Count).End(xlToLeft).Column 'find last column used
lr = Cells(Rows.Count, "A").End(xlUp).Row 'find last row of date
lastwed = Cells(1, lc) 'the last date
lmonth = Month(lastwed) 'month of the last date


If lmonth = 12 Then 'set the next month
    nmonth = 1
Else
    nmonth = lmonth + 1
End If


For x = 1 To 5 'loop to populate the next 4 or 5 wed
    If Month(Cells(1, lc + x - 1) + 7) = nmonth Then
        Cells(1, lc + x) = Cells(1, lc + x - 1) + 7
    Else
        Exit For
    End If
    
Next x


'copy formulas
nlc = Cells(1, Columns.Count).End(xlToLeft).Column 'find new last column used
Range(Cells(2, lc), Cells(lr, lc)).Copy Range(Cells(2, lc + 1), Cells(lr, nlc))


End Sub

 

[aletheasim96]

Hey Scott, I've tried it and it does exactly what i wanted it to! However, i have other data on the sheet above and below the rows im currently working on and when i run the code it works on all the rows. Is there a way to limit it to just rows 51 to 63? Sorry for not stating this in my original post and thanks so much for your time!

 

[Scott T]

This will only copy from rows 51 to 63 in the last column

Sub popwed()

Dim lc As Long
Dim lastwed As Date
Dim lmonth As Long
Dim nmonth As Long




lc = Cells(1, Columns.Count).End(xlToLeft).Column 'find last column used
lastwed = Cells(1, lc) 'the last date
lmonth = Month(lastwed) 'month of the last date


If lmonth = 12 Then 'set the next month
    nmonth = 1
Else
    nmonth = lmonth + 1
End If




For x = 1 To 5 'loop to populate the next 4 or 5 wed
    If Month(Cells(1, lc + x - 1) + 7) = nmonth Then
        Cells(1, lc + x) = Cells(1, lc + x - 1) + 7
    Else
        Exit For
    End If
    
Next x


'copy formulas
nlc = Cells(1, Columns.Count).End(xlToLeft).Column 'find new last column used
Range(Cells(51, lc), Cells(63, lc)).Copy Range(Cells(51, lc + 1), Cells(63, nlc))




End Sub

 

[aletheasim96]

Hey Scott, it works awesome Thanks so much man!!