vba code for Paste Charts as pictures erroring out

[Juno123]

Sub Test()
Dim ChObj As ChartObject
Dim wsReport As Worksheet
Dim Top As Double
Dim Left As Double
Application.ScreenUpdating = False
Set wsReport = Worksheets("ReportSheet")
For Each ChObj In wsReport.ChartObjects
Top = ChObj.Top
Left = ChObj.Left
ChObj.Cut
wsReport.Pictures.Paste.Select
Selection.Top = Top
Selection.Left = Left
Next ChObj
Range("A1").Select
Application.ScreenUpdating = True
End Sub

This macro code is failing with the following error-

Unable to set the Top property of the Range class

Can someone please help me with this, Its very critical for me.

Thanks in advance.

 

[Juno123]

The code is failing at the following line-

Selection.Top = Top

 

[Andrew Poulsom]

Your code worked perfectly for me in Excel 2003. The TypeName of Selection is a Picture not a Range, so I don't see how you can get that error.

 

[Norie]

This worked for me with a few charts, if what you are trying to do is replace all the charts with pictures that is.

It doesn't use Selection which might be the problem with your code.

Option Explicit

Sub Test()
Dim ChObj As ChartObject
Dim wsReport As Worksheet
Dim chTop As Double
Dim chLeft As Double
Dim chName As String
 
    Application.ScreenUpdating = False

    Set wsReport = Worksheets("ReportSheet")

    For Each ChObj In wsReport.ChartObjects
    
        chTop = ChObj.Top
        
        chLeft = ChObj.Left
        
        chName = ChObj.Name
        
        ChObj.CopyPicture xlScreen
        
        wsReport.Paste
        
        ChObj.Delete
        
        wsReport.Shapes(wsReport.Shapes.Count).Name = chName
        
        wsReport.Shapes(chName).Top = chTop
        
        wsReport.Shapes(chName).Left = chLeft
        
    Next ChObj
 
    Application.ScreenUpdating = True

End Sub

 

[RoryA]

As mentioned in your other post (please try not to duplicate them):

With wsReport.Pictures.Paste
   .Top = Top
   .Left = Left
End With