One formula to sum all lookup with different multiplication criteria

[zedoud]

Hi everyone,

I'm trying to solve this problem in an easy way. I have a database (1000s+ lines) with lines of sellers ID's and amount of sales over a time period. Each seller has a different commission percentage. I want to calculate the total amount of commission to be paid in one formula.

So far I have been doing this by having a different tab where I calculate the total commission calculate for each vendors with SUMIF and VLOOKUP:

For example for seller "AA" I want to have (1000+2200)*0.05:
=SUMIF(A:A;"AA";B:B)*VLOOKUP("AA";D:D;2)
And then sum the results I get of each seller vendors

Works fine but I want an easier way to do it in one short formula. Maybe using INDEX and Match? But I'm not to sure how to use it.

	A	B	C	D	E
1	Seller	Sold Value		Commission Rule
2	AA	1000		AA	5%
3	BB	1500		BB	6%
4	AA	2200		CC	4%
5	CC	3200
6	BB	2000

<colgroup><col span="2"><col><col span="3"></colgroup><tbody>
</tbody>

Thanks for your help!

P:S: Bonus if the formula includes a lookup for sellors with blank ID !

 

[sheetspread]

Excel 2010
	A	B	C	D	E
1	Seller	Sold Value		Commission Rule
2	AA	1000		AA	5%
3	BB	1500		BB	6%
4	AA	2200		CC	4%
5	CC	3200
6	BB	2000
7
8		498
Sheet1

Cell Formulas
Range	Formula
B8	=SUMPRODUCT(SUMIF($D$2:$D$4,$A$2:$A$6,$E$2:$E$4),$B$2:$B$6)

what would a blank return?

 

[zedoud]

Thanks a lot! This works great!

A blank would return the sum of the value of sales of sellers without ID (blanks) * a fixed commission (7%)

If I don't want to modify the database, I could just add to your formula =SUMPRODUCT(SUMIF($D$2:$D$4,$A$2:$A$7,$E$2:$E$4),$B$2:$B$7)+SUMIF($A$2:$A$7,"",$B$2:$B$7)*0,07 (if line 7 was a seller with no ID)

Or could I include this in the SUMPRODUCT?

Thanks!

Thanks!

 

[sheetspread]

If you add an ID of 0 blanks will be summed at the corresponding %:

Excel 2010
	A	B	C	D	E
1	Seller	Sold Value		Commission Rule
2	AA	1000		AA	5%
3	BB	1500		BB	6%
4	AA	2200		CC	4%
5		3200		0	7%
6	BB	2000
7
8		594
Sheet1

Cell Formulas
Range	Formula
B8	=SUMPRODUCT(SUMIF($D$2:$D$5,$A$2:$A$6,$E$2:$E$5),$B$2:$B$6)

 

[zedoud]

Perfect! Thanks a lot!

 

[zedoud]

Hi again,

I've been trying to add another criteria before multiplying. That is for example as below, only calculate for "Paris" seller. I've been trying with SUMIFS or adding array to the sumproduct formula but I either get nothing or error...

How could I add more criteria to the formula?

If you add an ID of 0 blanks will be summed at the corresponding %:

Excel 2010

	A	B	C	D	E
1	Seller	Sold Value	city	Commission Rule
2	AA	1000	¨Paris	AA	5%
3	BB	1500	NYC	BB	6%
4	AA	2200	NYC	CC	4%
5		3200	Paris	0	7%
6	BB	2000	NYC
7
8		594

<colgroup><col style="width: 25pxpx"><col><col><col><col><col></colgroup><thead>
</thead><tbody>
</tbody>

Sheet1​

Worksheet Formulas Cell Formula B8 =SUMPRODUCT(SUMIF($D$2:$D$5,$A$2:$A$6,$E$2:$E$5),$B$2:$B$6) <thead> </thead><tbody> </tbody>

<tbody>
</tbody>

Thanks!

 

[sheetspread]

Excel 2010
	A	B	C	D	E
1	Seller	Sold Value	city	Commission Rule
2	AA	1000	Paris	AA	5%
3	BB	1500	NYC	BB	6%
4	AA	2200	NYC	CC	4%
5		3200	Paris	0	7%
6	BB	2000	NYC
7
8	Paris	274
Sheet9

Cell Formulas
Range	Formula
B8	=SUMPRODUCT(SUMIF($D$2:$D$5,$A$2:$A$6,$E$2:$E$5),--($C$2:$C$6=A8),$B$2:$B$6)

 

[zedoud]

Thanks! Didn't know this "--" trick!