Copy and paste on hidden rows or columns

[Cris_Jon]

Hi

Please help on how i Can paste items if i have a column filtered or have rows that are hidden.

I filtered column A, so some rows are hidden, next I want to paste data on the filtered column with out changing the data on the hidden rows.

Thanks!

Do let me know if it is confusing.

 

[B4andafter]

Hope this helps....

Copy & Paste Visible Cells:
Select the entire range you want to copy--– Press Ctrl+C or Right-click>Copy.. Select the cell or range that you want to paste to and Press Alt+ to select the visible cells only (the filtered cells).. ... .
Paste the range – Press Ctrl+V or Right-click>Paste.

 

[B4andafter]

Sorry the above may not work for you but I found this thread in the forum:

https://www.mrexcel.com/forum/excel-questions/85288-paste-visible-cells-only.html

 

[Akuini]

I answered this similar problem in another thread.
https://www.mrexcel.com/forum/excel-...ered-list.html

Here is the code:

Sub CopyVisibleToVisible()
'Copy paste(value):
'from filtered to filtered range
'from filtered to unfiltered range
'from unfiltered to filtered range
'Not work on hidden column

    Dim rngA As Range
    Dim rngB As Range
    Dim r As Range
    Dim Title As String
    Dim ra As Long
    Dim rc As Long
    
    Title = "Copy Visible To Visible"
    Set rngA = Application.Selection
    Set rngA = Application.InputBox("Copy Range :", Title, rngA.Address, Type:=8)
    
    Set rngB = Application.InputBox("Paste Range (select the first cell only):", Title, Type:=8)
    Set rngB = rngB.Cells(1, 1)
    Application.ScreenUpdating = False

    ra = rngA.Rows.count
    rc = rngA.Columns.count
    Set rngA = rngA.Cells(1, 1).Resize(ra, 1)
    
    For Each r In rngA.SpecialCells(xlCellTypeVisible)
      rngB.Resize(1, rc).Value = r.Resize(1, rc).Value
        Do
          Set rngB = rngB.Offset(1, 0)
        Loop Until rngB.RowHeight <> 0
    Next
    
    Application.Goto rngB
    Application.ScreenUpdating = True
    Application.CutCopyMode = False

End Sub