MrExcel Publishing
Your One Stop for Excel Tips & Solutions

Is there a formula that will display the sheet name?


Posted by Travis on January 16, 2002 10:31 AM

Is there a formula that will display the sheet name?


Posted by thomas venn on January 16, 2002 10:37 AM

the function =cell("filename") will give you that sheet name, but it will also give you the entire path. hope this helps.

cheers,

- thomas

Posted by Nate Oliver on January 16, 2002 11:16 AM

Try the following on for size:

=MID(CELL("filename",A1),FIND("[",CELL("filename",A1))+1,FIND("]",
CELL("filename",A1))-FIND("[",CELL("filename",A1))-1)


Cheers! Nate

Posted by Nate Oliver on January 16, 2002 11:20 AM

I Suppose it would be of more help if I answered the question - Sheet name without path

Sorry, I gave you the filename...The following does the sheet name without the path:

=MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,
LEN(CELL("filename",A1))-FIND("]",CELL("filename",A1)))

Cheers!

Posted by Joe Was on January 16, 2002 12:02 PM

This is probably an easy one, but it doesn't matter if its easy if I can't do it!
I wish to conditionally lock cells... for example, if I have four cells next to each other in a row, and data is entered into one of those cells, I want to lock the other three cells to prevent data from being entered any of those three remaining, blank cells.
I'd appreciate any help. Thanks!

Posted by Parolles on January 17, 2002 5:57 AM

Here's another way .......


Create two Names as follows

Name : sheet
Refers to : =GET.DOCUMENT(76)

Name : wb
Refers to : =GET.DOCUMENT(88)

Enter the following formula in a worksheet cell
=SUBSTITUTE(SUBSTITUTE(sheet,wb,""),"[]","")
which will return the sheet name.

You can also just enter =wb which will give the workbook name, or =sheet which will give the workbook and sheet names in the format [WorkbookName]SheetName