Auto ordering

[EGP2018]

Hi, I've managed to find some VBA code on Google that will automatically order my data (below), but it's not quite what I need.

I'm looking at entering a job number in column A, an order in column B and then text in column C.
Once the text is entered in C, I'd like my data to automatically re-order by A then B.

Is this do-able? If so, can someone help me out?

Thanks in advance.

Private Sub Worksheet_Change(ByVal Target As Range)
On Error Resume Next
Range("A1").Sort Key1:=Range("A2"), _
Order1:=xlAscending, Header:=xlYes, _
OrderCustom:=1, MatchCase:=False, _
Orientation:=xlTopToBottom End Sub

 

[mumps]

I'm not sure if I understood correctly, but copy and paste this macro into the worksheet code module. Do the following: right click the tab name for your sheet and click 'View Code'. Paste the macro into the empty code window that opens up. Close the code window to return to your sheet. Enter a job number in column A, an order in column B and then text in column C and press the RETURN key.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Intersect(Target, Range("C:C")) Is Nothing Then Exit Sub
    Application.ScreenUpdating = False
    Dim LastRow As Long
    LastRow = Cells.Find("*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    With ActiveSheet.Sort
        .SortFields.Clear
        .SortFields.Add Key:=Range("A2:A" & LastRow), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SortFields.Add Key:=Range("B2:B" & LastRow), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        .SetRange Range("A1:C" & LastRow)
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Application.ScreenUpdating = True
End Sub

 

[EGP2018]

It answers it perfectly thank you.

The SME did miss one bit out though!
Will this code sort all columns? For example, there could be text entered in columns D to P inclusive that will need to align with A,B and C.

 

[EGP2018]

Ignore the above - I've managed to amend.

Many thanks for your help!

 

[mumps]

You are very welcome.