Calculating Time Error

[andrewb90]

Hello All,

I am running a formula that will count the number of employees scheduled at a particular time. (Each formula references a different hour). In addition to what is an incredibly long formula, I now have discovered that if a shift is scheduled to end past 23:59, then the entire shift will not be counted.
Can somebody assist me in fixing this, and if you have any hints of shortening this formula, that would be greatly appreciated.

Code:
=(SUM(IF(E$87:E$111<$B87,IF(F$87:F$111>$A87,IF(F$87:F$111<$B87,F$87:F$111,$B87)-IF(E$87:E$111>$A87,E$87:E$111,$A87))))*24)+(SUM(IF(E$113:E$137<$B87,IF(F$113:F$137>$A87,IF(F$113:F$137<$B87,F$113:F$137,$B87)-IF(E$113:E$137>$A87,E$113:E$137,$A87))))*24)+(SUM(IF(E$139:E$146<$B87,IF(F$139:F$146>$A87,IF(F$139:F$146<$B87,F$139:F$146,$B87)-IF(E$139:E$146>$A87,E$139:E$146,$A87))))*24)+(SUM(IF(E$148:E$156<$B87,IF(F$148:F$156>$A87,IF(F$148:F$156<$B87,F$148:F$156,$B87)-IF(E$148:E$156>$A87,E$148:E$156,$A87))))*24)
Thanks,

Andrew

 

[joeu2004]

The problem is that if a shift runs past midnight (00:00) then the formulas completely ignore the entire shift

The problem arises because you (should) count shifts that start before the time period and end after the time period. Shifts ending after midnight do meet both conditions.

Try one of the following solutions.

	A	B	C	D	E	F	G
1	Solution #1
2	Joe	8:00	14:00		14:00	15:00	1
3	Sara	15:00	21:00		15:00	16:00	2
4	Bob	18:00	0:30		16:00	17:00	2
5	Sam	17:00	23:30		17:00	18:00	3
6	Chad	14:00	19:00		18:00	19:00	4
7					19:00	20:00	3

<tbody>
</tbody>

Enter the following formula into G2, and copy down:

=COUNTIFS($B$2:$B$6, "<=" & E2, $C$2:$C$6, ">=" & F2)

When shifts start before midnight, the key is to enter after-midnight times as a formula, like the following in C4:

=1 + "0:30"

Note the double-quotes around the actual time. All time cells are formatted as Custom hh:mm.

	A	B	C	D	E	F	G
1	Solution #2
2	Joe	8:00	14:00		14:00	15:00	1
3	Sara	15:00	21:00		15:00	16:00	2
4	Bob	18:00	0:30		16:00	17:00	2
5	Sam	17:00	23:30		17:00	18:00	3
6	Chad	14:00	19:00		18:00	19:00	4
7					19:00	20:00	3

<tbody>
</tbody>

Array-enter (press ctrl+shift+Enter instead of just Enter) the following formula into G2, and copy down:

=SUM(IF($B$2:$B$6<=E2, IF($C$2:$C$6+($C$2:$C$6<$B$2:$B$6)>=F2, 1)))

Excel displays the array-entered formula with curly braces around it.

In this case, all times are entered as they appear. In particular, C4 is simply 0:30.

Note that this approach works only for shifts of less than 24 hours.

 

[joeu2004]

PS for solution #2....

Array-enter (press ctrl+shift+Enter instead of just Enter) the following formula into G2, and copy down:
=SUM(IF($B$2:$B$6<=E2, IF($C$2:$C$6+($C$2:$C$6<$B$2:$B$6)>=F2, 1)))

Better.... Normally-enter (just press Enter as usual) the following formula into G2, and copy down:

=SUMPRODUCT(($B$2:$B$6<=E3)*($C$2:$C$6+($C$2:$C$6<$B$2:$B$6)>=F3))

In this context, the multiplication (*) performs an AND operation.

 

[andrewb90]

[QUOTE

When shifts start before midnight, the key is to enter after-midnight times as a formula, like the following in C4:

=1 + "0:30"

Note the double-quotes around the actual time. All time cells are formatted as Custom hh:mm.

.[/QUOTE]

The only issue that I have is making the user type in a formula. I'm trying to make it as computer illiterate as necessary.

 

[joeu2004]

The only issue that I have is making the user type in a formula. I'm trying to make it as computer illiterate as necessary.

Understandable. I anticipated that. That's why I offered the SUMPRODUCT alternative as well (solution #2, modified by my "PS" follow-up). That does not require any special input.

PS: But hopefully the 1+"0:30" approach helps you understand what we are accomplishing with the SUMPRODUCT alternative. We are simply adding 1 (1 day; 24 hours) in the formula instead of in the data.