Converting Row to Column Format

[cantab04]

Hello, I am trying to convert the following table:

ID Number	Purchase Amount	Purchase Type
23	$86	Product X
24	$56	Product Y
25	$66	Product X
23	$88	Product Y
23	$90	Product Z

<tbody>
</tbody>

into this format:

ID Number	Purchase Amount 1	Purchase Type 1	Purchase Amount 2	Purchase Type 2	Purchase Amount 3	Purchase Type 3
23	$86	Product X	$88	Product Y	$90	Product Z
24	$56	Product Y
25	$66	Product X

<tbody>
</tbody>

Essentially, I need for Excel to recognize instances in which a unique identifier (ID here) is represented on multiple rows, and then convert the data associated with these instances into a Column format.

I have KUTools and have a basic understanding of VBA. Any help is much appreciated!

 

[JoeMo]

This assumes your initial table starts in A1 and rearranges the table starting in E1 of the same worksheet.

Sub RearrangeData()
'assumes initial data headers start in A1 of the active sheet
Dim Rtbl As Range, Rdata As Range, V As Variant, Cols As Long, i As Long, j As Long, nxCol As Long
Set Rtbl = Range("A1").CurrentRegion
Set Rdata = Rtbl.Offset(1, 0).Resize(Rtbl.Rows.Count - 1)
V = Rdata.Value
Application.ScreenUpdating = False
'how many columns needed
Cols = Application.Max(Application.CountIf(Rdata.Columns(1), Rdata.Columns(1)))
'rearrange data starting in E1
Range("E1").Resize(1, 2 * Cols + 1).EntireColumn.ClearContents
Rtbl.Columns(1).AdvancedFilter Action:=xlFilterCopy, copytorange:=[E1], unique:=True
j = 1
For i = 1 To 2 * Cols Step 2
    Range("E1").Offset(0, i) = "Purchase Amount " & j
    Range("E1").Offset(0, i + 1) = "Purchase Type " & j
    j = j + 1
Next i
Range("E1").CurrentRegion.EntireColumn.AutoFit
For Each c In Range("E2:E" & Cells(Rows.Count, "E").End(xlUp).Row)
    For i = LBound(V, 1) To UBound(V, 1)
        If V(i, 1) = c.Value Then
            nxCol = Cells(c.Row, Columns.Count).End(xlToLeft).Column + 1
            Cells(c.Row, nxCol) = V(i, 2)
            Cells(c.Row, nxCol + 1) = V(i, 3)
        End If
        Next i
        nxCol = 0
Next c
Application.ScreenUpdating = True
End Sub

 

[cantab04]

Thank you Joe! I will try this out and report back.