How do I strip out all non-numeric characters?

exceltm

New Member
How do I strip out all non-numeric characters?

I have 10,000 phone numbers, of which people entered in different formats, such as
212.123.1234
212 123 1234
212-123-1234
(212)123-1234

How do I strip out ALL the data/characters that are NOT numbers so the result is

2121231234

I want all my phone numbers to be consistent. I can individually FIND and REPLACE the .()- and spaces with "" nothing but sometimes there remain hidden characters after the 10 numbers. I know this from doing a =LEN(A1) and it reports 11, even though I see only 10 numbers. If I highlight the field and hit delete at the end of the 10 numbers, it deletes SOMETHING which is invisible and takes the length to 10 numbers as it should be.

So, how do I strip out ALL the data/characters that are NOT numbers so the result is only the 10 numbers?
 

Jon von der Heyden

MrExcel MVP, ModeratorTracy's new best bud
Another way if you have Morefunc:

Excel Workbook
AB
1212.123.12342121231234
2212 123 12342121231234
3212-123-12342121231234
4(212)123-12342121231234
example
Excel 2003
Array Formulas
CellArray Formula
B1=--MCONCAT(IF(ISNUMBER(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)),MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),""))
Press CTRL+SHIFT+ENTER to enter array formulas.
Entered with Ctrl+Shift+Enter. If entered correctly, Excel will surround with curly braces {}. Note: Do not try and enter these manually yourself
 

Richard Schollar

MrExcel MVP
I'm rather keen on this formula courtesy of Ron Coderre:
Excel Workbook
AB
24212.123.12342121231234
Sheet1
Excel 2002
Cell Formulas
CellFormula
B24=SUMPRODUCT(MID(0&A24,LARGE(INDEX(ISNUMBER(--MID(A24,ROW($1:$25),1))* ROW($1:$25),0),ROW($1:$25))+1,1)*10^ROW($1:$25)/10)
 

Jon von der Heyden

MrExcel MVP, ModeratorTracy's new best bud
I'm rather keen on this formula courtesy of Ron Coderre:

Excel Workbook
AB
24212.123.12342121231234
Sheet1
Excel 2002
Cell Formulas
CellFormula
B24=SUMPRODUCT(MID(0&A24,LARGE(INDEX(ISNUMBER(--MID(A24,ROW($1:$25),1))* ROW($1:$25),0),ROW($1:$25))+1,1)*10^ROW($1:$25)/10)
Wow :eek:
One for the favourites list. (y)
 

exceltm

New Member
This works perfectly except for when the cell is blank/empty, it returns a value of zero/0.

THanks to all for the superfast replies. My skill level is beginner.

I'm rather keen on this formula courtesy of Ron Coderre:

Excel Workbook
AB
24212.123.12342121231234
Sheet1
Excel 2002
Cell Formulas
CellFormula
B24=SUMPRODUCT(MID(0&A24,LARGE(INDEX(ISNUMBER(--MID(A24,ROW($1:$25),1))* ROW($1:$25),0),ROW($1:$25))+1,1)*10^ROW($1:$25)/10)
 

Richard Schollar

MrExcel MVP
You could test for that in an IF statement:

=IF(A1="","",SUMPRODUCT(MID(0&A1,LARGE(INDEX(ISNUMBER(--MID(A1,ROW($1:$25),1))*
ROW($1:$25),0
),ROW($1:$25)
)+1,1
)*10^ROW($1:$25)/10
))
 

Some videos you may like

This Week's Hot Topics

Top