IE6 Automation in VBA - automating child page on butt******* in parent page

[Bhups]

Hi,

My query is regarding internet explorer 6 automation via code in VBA (Excel 2003). I'm trying to open a page on clicking a button in main page.

I'm able to open both parent and child pages via VBA, but now want to automate events (like radio btn click etc) in child page.

Could you please help me in achieveing this?

below is my initial code -

'========
Sub ListLinks()
Dim IeApp As InternetExplorer
Dim sURL As String
Dim IeDoc As Object
Dim i As Long
 
'Create new instance of IE
Set IeApp = New InternetExplorer
 
'Make it visible - some things don’t work
'unless it’s visible
IeApp.Visible = True
 
'define the page to open
sURL = "http://test/welcome.aspx"
 
'navigate to the page
IeApp.Navigate sURL
 
'Pause the macro using a loop until the
'page is fully loaded
Do
Loop Until IeApp.ReadyState = READYSTATE_COMPLETE
 
'store the Document object
Set IeDoc = IeApp.Document
 
 
'click a button on the main page
Set ElementCol = IeDoc.getElementsByTagName("INPUT")
For Each btnInput In ElementCol
If btnInput.Value = "Open" Then
Set IeApp.Document = btnInput.Click 'This will open up another IE window
Exit For
End If
Next btnInput
 
'Clean up
Set IeApp = Nothing
IeApp.Quit
 
End Sub
'===========

Thanks,
Bhups

 

[Legacy 98055]

Here is a sample search. You could do this with much less code but I wrote it as such for illustration.

Option Explicit

Private WithEvents IeApp As InternetExplorer
Private WithEvents NewWindow As InternetExplorer

'requires two references
'Microsoft Internet Controls
'Microsoft HTML Object Library
Sub ListLinks()
Dim sURL As String
Dim IeDoc As Object
Dim i As Long
Dim ElementCol As Object
Dim btnInput As Object

'Create new instance of IE
Set IeApp = Nothing
Set IeApp = New InternetExplorer

'Make it visible - some things don’t work
'unless it’s visible
IeApp.Visible = True

'define the page to open
sURL = "http://www.tfl.gov.uk/"

'navigate to the page
IeApp.Navigate sURL

'Pause the macro using a loop until the
'page is fully loaded
Do
Loop Until IeApp.ReadyState = READYSTATE_COMPLETE

'store the Document object
Set IeDoc = IeApp.Document


'click a button on the parent page
Set ElementCol = IeDoc.getElementsByTagName("INPUT")
For Each btnInput In ElementCol
If btnInput.Value = "Search" Then
btnInput.Click
Exit For
End If
Next btnInput

'Clean up
'Set IeApp = Nothing
'IeApp.Quit

End Sub

Private Sub IeApp_NewWindow2(ppDisp As Object, Cancel As Boolean)
    Set NewWindow = New InternetExplorer
    Set ppDisp = NewWindow
End Sub

Private Sub NewWindow_DocumentComplete(ByVal pDisp As Object, URL As Variant)
    'using ontime allows the event to return
    Application.OnTime Now, Me.CodeName & ".ProcessNewWindow"
End Sub

Sub ProcessNewWindow()
    Dim Doc As HTMLDocument
    Dim Form As HTMLFormElement
    Dim KeyWords As HTMLInputTextElement
    Dim CompanyName As HTMLInputTextElement
    Dim Location As HTMLInputTextElement

    Set Doc = NewWindow.Document
    Set Form = Doc.getElementById("searchBoxForm_bottom")
    Set KeyWords = Doc.getElementById("keywordsInput_bottom")
    Set CompanyName = Doc.getElementById("companyName_bottom")
    Set Location = Doc.getElementById("location_bottom")
    
    KeyWords.Value = "Dry cleaning & laundry"
    CompanyName.Value = "Morrisons"
    Location.Value = "Camden Town"
    Form.submit
End Sub

 

[Bhups]

Thanks alot Tom. It was really helpful.