Need to apply loop to IsNumber values only

[drmingle]

Objective: to appy rounding vba code to user selected rangeConcerns: I only want this to apply to IsNumeric values. In some cases, the users may select blank cells and cells with text (these cells should be skipped).I can get the below code to work, but not when it enconters blank cells or cells with text values.Any help would be appreciated...

Sub Round()
Dim cell As Range
    For Each cell In Application.Selection.Cells
        'If cell.Value.IsText() Then ActiveCell.Offset(1, 0).Select
        If cell.Value.IsNumber() Then
            cell.Value = WorksheetFunction.Round(cell.Value, 0)
        Else
            ActiveCell.Offset(1, 0).Select
    Next cell
End Sub

 

[Chris Mack]

Possibly something like:

Sub Round()
Dim cell As Range
    For Each cell In Application.Selection.Cells
        If cell.Value = "" Then GoTo nextcell
        If IsNumeric(cell.Value) = False Then GoTo nextcell
        cell.Value = WorksheetFunction.Round(cell.Value, 0)
nextcell:
    Next cell
End Sub

Test in a practice workbook first.

Hope this helps,

Chris.

 

[drmingle]

Chris,

That works perfectly...thank you for the fast response.

 

[Chris Mack]

You're welcome!

 

[Rick Rothstein]

That works perfectly...thank you for the fast response.

I would suggest you not use IsNumeric (either stick with the worksheetfunction's IsNumber of use the appropriate function from below). Both Chris and you might find this previous posting of mine to be of interest.

I have this "thing" against the IsNumeric function, so many years ago (back in my volunteering days for the compiled version of VB) I used to post this message to the then newsgroups that covered user questions before forums became popular, I think it kind of explains the "why" of it...

From a previous post of mine...

I usually try and steer people away from using IsNumeric to "proof" supposedly numeric text. Consider this (also see note below):

ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some "flaws" in what it considers a proper number and what most programmers are looking for.

I had a short tip published by Pinnacle Publishing in their Visual Basic Developer magazine that covered some of these flaws. Originally, the tip was free to view but is now viewable only by subscribers.. Basically, it said that IsNumeric returned True for things like -- currency symbols being located in front or in back of the number as shown in my example (also applies to plus, minus and blanks too); numbers surrounded by parentheses as shown in my example (some people use these to mark negative numbers); numbers containing any number of commas before a decimal point as shown in my example; numbers in scientific notation (a number followed by an upper or lower case "D" or "E", followed by a number equal to or less than 307 -- the maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and commas and dots -- these were meant to refer to your currency, thousands separator and decimal point symbols as defined in your local settings -- substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I have posted in the past for similar questions..... one is for digits only and the other is for "regular" numbers (the code is simple enough that it can be pulled from the function "housing" and used directly inside your own code):

Function IsDigitsOnly(Value As String) As Boolean
    IsDigitsOnly = Len(Value) > 0 And Not Value Like "*[!0-9]*"
End Function

Function IsNumber(ByVal Value As String) As Boolean
    '   Leave the next statement out if you don't
    '   want to provide for plus/minus signs
    If Value Like "[+-]*" Then Value = Mid$(Value, 2)
    IsNumber = Not Value Like "*[!0-9.]*" And Not Value Like "*.*.*" And Len(Value) > 0 And Value <> "."
End Function

Here are revisions to the above functions that deal with the local settings for decimal points (and thousand's separators) that are different than used in the US (this code works in the US too, of course).

Function IsNumber(ByVal Value As String) As Boolean
  Dim DP As String
  '   Get local setting for decimal point
  DP = Format$(0, ".")
  '   Leave the next statement out if you don't
  '   want to provide for plus/minus signs
  If Value Like "[+-]*" Then Value = Mid$(Value, 2)
  IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
             DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
End Function

I'm not as concerned by the rejection of entries that include one or more thousand's separators, but we can handle this if we don't insist on the thousand's separator being located in the correct positions (in other words, we'll allow the user to include them for their own purposes... we'll just tolerate their presence).

Function IsNumber(ByVal Value As String) As Boolean
  Dim DP As String
  Dim TS As String
  '   Get local setting for decimal point
  DP = Format$(0, ".")
  '   Get local setting for thousand's separator
  '   and eliminate them. Remove the next two lines
  '   if you don't want your users being able to
  '   type in the thousands separator at all.
  TS = Mid$(Format$(1000, "#,###"), 2, 1)
  Value = Replace$(Value, TS, "")
  '   Leave the next statement out if you don't
  '   want to provide for plus/minus signs
  If Value Like "[+-]*" Then Value = Mid$(Value, 2)
  IsNumber = Not Value Like "*[!0-9" & DP & "]*" And Not Value Like "*" & _
             DP & "*" & DP & "*" And Len(Value) > 0 And Value <> DP
End Function

 

[Chris Mack]

Thanks for sharing, Rick.

So I'm guessing a more reliable version would be:

Sub Round()
Dim cell As Range
    For Each cell In Application.Selection.Cells
        If cell.Value = "" Then GoTo nextcell
        If Application.WorksheetFunction.IsNumber(cell.Value) = False Then GoTo nextcell
        cell.Value = WorksheetFunction.Round(cell.Value, 0)
nextcell:
    Next cell
End Sub

I'll test it tomorrow.

Chris.