Needed Macro Code to create graphs

[Rampage598]

Excel File Download Link

I'm looking to generate a 2D line graph across multiple worksheets with varying amounts of row data. I need help creating the same type of graph depicted in an image for each worksheet. Could someone assist me in developing a macro code to achieve this task across all sheets?

I have attached my Excel file download link,

I'd like to replicate two manually created graphs found in the "23104137" sheet across all other sheets in the Excel file. Could someone assist me by providing a macro code to achieve this?

 

[Jon Peltier]

First, you probably ought to use XY Scatter charts, which plot the date/time values as numbers, not nonnumeric labels. But that's up to you.

I would start with something like this. You will have to modify formatting of the charts, of course.

Sub ChartsOnEachWorksheet()
  Dim ws As Worksheet
  For Each ws In ActiveWorkbook.Worksheets
    If IsNumeric(ws.Name) Then
      Dim rng As Range
      Set rng = ws.Range("A1").CurrentRegion
      ' first chart
      Dim r1source As Range ' source data
      Set r1source = rng.Resize(, 4)
      Dim r1tlc As Range ' top left cell
      Set r1tlc = ws.Range("I2")
      Dim cht1 As Chart
      Set cht1 = ws.Shapes.AddChart2(, xlXYScatterLinesNoMarkers, r1tlc.Left, r1tlc.Top).Chart
      cht1.SetSourceData r1source
      cht1.SeriesCollection(1).AxisGroup = xlSecondary
      ' second chart
      Dim r2source As Range
      Set r2source = Union(rng.Resize(, 1), rng.Resize(, 2).Offset(, 4))
      Dim r2tlc As Range ' top left cell
      Set r2tlc = ws.Range("I17")
      Dim cht2 As Chart
      Set cht2 = ws.Shapes.AddChart2(, xlXYScatterLinesNoMarkers, r2tlc.Left, r2tlc.Top).Chart
      cht2.SetSourceData r2source
    End If
  Next
End Sub