Nested formula

[blandreth]

I'm looking for a formula that will provide the following result:

If b9= selection "a","b",or "c" and b11 is populated then result would be "ok to save"

If b9= selection "D", then look for B20 and if it is populated the result would be "ok to save"

otherwise result would be "not ready to save"

for example - if b9="a" and b11 was empty result would be "not ready to save" - if b9="a" and b11 is populated then result would be "ok to save"

for example - if b9="d" and b20 was empty result would be "not ready to save" - if b9="d" and b20 is populated then result would be "ok to save"

Running Excel 2016

Any suggestions would be greatly appreciated.

Thanks,
Brian

 

[cerfani]

=IF(AND(OR(B9="a",OR(B9="b",B9="c")),NOT(ISBLANK(B11))),"ok to save","not ready to save")

try that

 

[mumps]

Try this formula: =IF(AND(OR(B9="a",B9="b",B9="c"),B11<>""),"OK to save",IF(AND(B9="d",B20<>""),"OK to save",""))

 

[C with no eyes]

=IF(AND(OR(B9="a",B9="b",B9="c"),B11<>""),"OK to save",IF(AND(B9="D",B20<>""),B20,"Not ready to save"))

 

[blandreth]

Worked like a champ.

Thank you so much!!

 

[mumps]

Modified from Post #3 : =IF(AND(OR(B9="a",B9="b",B9="c"),B11<>""),"OK to save",IF(AND(B9="d",B20<>""),"OK to save","Not ready to save"))

 

[blandreth]

Thanks! This worked great.

BTW - love the avatar \m/

 

[mumps]

Glad to help. I was a drummer in my younger days!!!!

 

[blandreth]

That's awesome! I'm still a drummer

 

[jtakw]

Hi,

Same formula, just a little shorter:

=IF(OR(AND(OR(B9={"a","b","c"}),B11<>""),AND(B9="d",B20<>"")),"OK to save","Not ready to save")