Referencing Text Cell within Formula

[jim may]

I'm vaguely familiar with the INDIRECT() formula, but not enough to solve my problem.

In my Worksheet Named MAIN I currently have the formula (WHICH WORKS!!):

=SUM('Aug 2017'!K25:K28)

I was to modify the above so that I can reference in the 'Aug 2017' portion using another reference.

In my MAIN sheet Cell C1 I have the general number 8 << representjng my calendar Month #.

I have Another Worksheet Named LOOKUPDATA set up as follows:

Excel 2010

	A	B	C	D	E	F	G
1
2
3		SS	Nancy's Pay Checks
4	Month	Wednesday	First	Second	Third	WS Names	MonthEnd
5	1	1/25/2017	1/6/2017	1/20/2017		Jan 2017	1/31/2017
6	2	2/22/2017	2/3/2017	2/17/2017		Feb 2017	2/28/2017
7	3	3/22/2017	3/3/2017	3/17/2017	3/31/2017	Mar 2017	3/31/2017
8	4	4/26/2017	4/14/2017	4/28/2017		Apr 2017	4/30/2017
9	5	5/24/2017	5/12/2017	5/26/2017		May 2017	5/31/2017
10	6	6/28/2017	6/9/2017	6/23/2017		Jun 2017	6/30/2017
11	7	7/26/2017	7/7/2017	7/21/2017		Jly 2017	7/31/2017
12	8	8/23/2017	8/4/2017	8/18/2017		Aug 2017	8/31/2017
13	9	9/27/2017	9/1/2017	9/15/2017	9/29/2017	Sep 2017	9/30/2017
14	10	10/25/2017	10/13/2017	10/27/2017		Oct 2017	10/31/2017
15	11	11/22/2017	11/10/2017	11/24/2017		Nov 2017	11/30/2017
16	12	12/27/2017	12/8/2017	12/22/2017		Dec 2017	12/31/2017

<tbody>
</tbody>

LookUpData

​

So I'm hoping in my original formula to reference in the value in Cell F12 above which is Text - using the
VLOOKUP() and the Indirect().

Can someone assist?

Thanks in Advance.

Jim

 

[RoryA]

I think you mean:

=SUM(INDIRECT("'"&VLOOKUP(C1,LOOKUPDATA!A:F,6,FALSE)&"'!K25:K28"))

 

[Jonmo1]

Or

=SUM(INDIRECT("'"&INDEX(LOOKUPDATA!F:F,C1)&"'!K25:K28"))

Or if Current Year can be assumed

=SUM(INDIRECT("'"&TEXT(C1&"/1","mmm yyyy")&"'!K25:K28"))

 

[RoryA]

The lookup table doesn't start in row 1, so you'll need an offset amount added to get the correct row if you just use C1 directly.

 

[Jonmo1]

Good point, that would have to be

=SUM(INDIRECT("'"&INDEX(LOOKUPDATA!F$5:F$16,C1)&"'!K25:K28"))

 

[jim may]

Thanks Guys!! Got it working -- Jim