Suggested formula?

[IanBr]

Me again,

I have a table along the lines of:

a	1	123
b	1	34
c	1	235423
d	1	2435
a	2	214
b	3	2354
b	2	2352

<tbody>
</tbody>

Where first column is an account number, the second is the sequence of the sale and the 3rd is the value of the sale. What I want to do is to have a formula in the 4th column along the lines of "if this is not the first sale, what was the value of the first sale"

So for example the returned value against the 5th line would be 123 (line 5 is the second sale to a and the first sale was for 123)

Any ideas?

I got as far as =if(a5>1,vlookup(a5,a1:c7,3,0),"nil") however this wouldn't necessarily pick up the first sale to "a" so there needs to be some sort of search to find the row where column a is a and column b is 1 and return value from column c of this row

 

[Eric W]

Try:

	A	B	C	D	E	F
1	a	1	123
2	b	1	34
3	c	1	235423
4	d	1	2435
5	a	2	214		123
6	b	3	2354		34
7	b	2	2352		34

<tbody>
</tbody>

Sheet8​

Worksheet Formulas Cell Formula E1 =IF(B1=1,"",SUMIFS($C$1:$C$10,$A$1:$A$10,A1,$B$1:$B$10,1)) <tbody> </tbody>

<tbody>
</tbody>

 

[Fluff]

How about
=IF(B1=1,"nil",SUMPRODUCT((A$1:A$7=A1)*(B$1:B$7=1),(C$1:C$7)))

 

[IanBr]

Thank you both.

Both of the above work!

Next step... can it be adapted so that it only returns values for each customer on one line so for example in Eric W's solution shown above, lines 6 and 7 return the answer 34 (correctly). Ideally I only want to see first spend value against the most recent sale (i.e in the above row 6 would return 34, line 7 would return blank)

Thanks again

 

[Fluff]

How about
=IF(OR(B1=1,COUNTIF(A$1:A$7,A1)<>B1),"",SUMPRODUCT((A$1:A$7=A1)*(B$1:B$7=1),(C$1:C$7)))

 

[Eric W]

Or:

=IF(COUNTIF($A$1:$A1,A1)<>2,"",SUMIFS($C$1:$C$10,$A$1:$A$10,A1,$B$1:$B$10,1))