Combining if statement and Isblank

[kimparker0261]

I have the formula for this spreadsheet, if cell a2 is greater than 0 then display the information from a new sheet and the cell f9, but I also need to put in the if statement if the cell is blank then dont display any information. Can this formula be done .

this is the first half of the formula to show if the cell is less greater than zero to display the information on the other sheet from cell F9, the help I need is to update the formula to say If A2 is blank then leave the cell blank.
<code style="margin: 0px; padding: 0px; border: 0px; font-style: inherit; font-variant: inherit; font-weight: inherit; font-stretch: inherit; line-height: inherit; font-family: Consolas, Menlo, Monaco, "Lucida Console", "Liberation Mono", "DejaVu Sans Mono", "Bitstream Vera Sans Mono", "Courier New", monospace, sans-serif; vertical-align: baseline; box-sizing: inherit; white-space: inherit;">=IF(A2>0,Sheet2!F9,"")
</code>

 

[kimparker0261]

How can I send you a sample of the sheet

 

[Fluff]

You would have to upload it it to a share site such as OneDrive, Dropbox, Googledrive, mark for sharing & then post a link to the thread

 

[kimparker0261]

hi this is the link
https://1drv.ms/x/s!AoRYGdvX8gxwgVcK1aoWsJmw6Gtq

 

[Fluff]

How about
=IF(OR(Input!C4="",Input!C4<=0),"",Input!D4)
When you copy that down you will get a value for Input!c6 as it's not blank

 

[kimparker0261]

Hi, that work for the value of zero
Question is it likely that if the cell is blank or when i clear it out with the space bar that it would not work.

 

[Fluff]

If you "clear it out" with the space bar, then the cell is not blank as it contains a space.
To clear the cell select it & then press delete on the keyboard.

 

[kimparker0261]

You just made me the happiest person in the world thank you so much it is working, I was going crazy.

 

[Fluff]

You're welcome

 

[kimparker0261]

I have one last question for you,
Now that the formula is working and it is updating the output sheet, do you know of any way that the sheet can automatic sort by the qty so the zeros or blanks rows would not be shown

 

[Fluff]

Whilst it won't sort it will remove the blanks & 0s

Excel 2013/2016
	C	D	E
4	2	test	PLATFORM, FORMED, 95.875 x 87.50 plywood, DE CO
5	2	1356	5555
6	3	798BX4-SP	STILE, FORMED, 8" X XXX" LG., SPECIAL UX
7
8
9
10
11
12
13
14
output

Cell Formulas
Range	Formula
C4	{=IFERROR(INDEX(Input!C$4:C$9,SMALL(IF((Input!$C$4:$C$9<>"")*(Input!$C$4:$C$9>0),ROW(Input!$C$4:$C$9)-ROW(Input!$C$4)+1),ROWS($1:1))),"")}
D4	{=IFERROR(INDEX(Input!D$4:D$9,SMALL(IF((Input!$C$4:$C$9<>"")*(Input!$C$4:$C$9>0),ROW(Input!$C$4:$C$9)-ROW(Input!$C$4)+1),ROWS($1:1))),"")}
E4	{=IFERROR(INDEX(Input!E$4:E$9,SMALL(IF((Input!$C$4:$C$9<>"")*(Input!$C$4:$C$9>0),ROW(Input!$C$4:$C$9)-ROW(Input!$C$4)+1),ROWS($1:1))),"")}
Press CTRL+SHIFT+ENTER to enter array formulas.