Apex of a bell curve

[jondavis1987]

I have a scatter chart with smooth lines that creates a bell curve. Is there a formula i can make based off of the data to calculate the apex of the bell curve or is there an excel function to show the apex number and label it?

 

[jondavis1987]

I'm plotting a proctor for soils. The D21:G21 contains moisture contents. D29:G29 contains densities. The top of the curve shows me where the optimum density and the optimum moisture is. I tried the macro on it. It's not really close enough for what i need to do. I tried some sample data with it and it produced a number that was decently far away from the apex.

 

[shg]

You could help yourself if you'd be a little more forthcoming with information. No one has any idea what data you're looking at or what you're trying do do.

Post your data, explain what it means, explain what you're trying to do, post a web link for reference, something.

If you'd invest a little effort, you would likely be well rewarded.

 

[jondavis1987]

I'm plotting basically a polynomial line with an order of 3 (I was using a scatter chart with smooth curves but i just switched to polynomial trendline) using the x cordinates from D21:G21 and the Y cordinates from D29:G29. The apex (or the top of the line before it starts going down in the curve) where it cordinates with the y axis and the x axis is what i want it to lift. So the y axis is going to be between 100 and 110 for instance. The x axis is going to be between 9 and 20. If the top of the curve on a polynomial line falls on the x axis at 14.2 and the y axis of 105.6, I would like it to automatically generate those numbers.

It charts something like this chart in the link http://www.engineeringcivil.com/det...and-the-optimum-moisture-content-of-soil.html

I want something to analyze the numbers that plug into it from D21:G21 (Xaxis) & D29:G29 (Y Axis) and generates those numbers

<tbody>
</tbody>

I've invested a fair amount of effort into this. I've given all of the information there is to have on this.

 

[shg]

You can get the coefficients of the polynomial using LINEST.

The derivative of the polynomial a3 * x^3 + a2 * x^2 + a1 * x + a0 is 3 * a3 * x^2 + 2 * a2 * x + a1

Solve that for zero using the quadratic formula.

 

[shg]

If you post your actual data in copyable format, I'll show you.

 

[jondavis1987]

https://www.dropbox.com/s/50nisl0ml754m59/Soils Workbook 1.xlsx?dl=0 I have some sample data filled into this. It's worksheet T-99

The data points are
X axis D21-13.8 E21-15.0 F21-16.4 G21-18.5
Y axis D29-102.2 E29-107.6 F29-108.7 G29-103.6

It might also change to three data points or five but if i get the basic formula of it i should be able to figure that part out on my own i think

 

[shg]

	C​	D​	E​	F​	G​	H​	I​
21​	x​	13.8​	15​	16.4​	18.5​
29​	y​	102.2​	107.6​	108.7​	103.6​
30​	​
31​	exp​	3​	2​	1​	0​
32​	coeff​	0.1085541​	-6.33521​	119.3858​	-624.134​		D32:G32: {=LINEST(D29:G29, D21:G21^{1;2;3})}
33​	​
34​	fit​	102.2​	107.6​	108.7​	103.6​		D34 and across: =SERIESSUM(D21, 3, -1, $D$32:$F$32) + $G$32
35​	​
36​	exp​	2​	1​	0​
37​	derivative​	0.3256622​	-12.6704​	119.3858​			D37 and across: =D31*D32
38​	​
39​	Extrema 1​
40​	x​	16.012668​					D40: =(-E37 - SQRT(E37^2 - 4 * D37 * F37)) / (2 * D37)
41​	y​	108.8618​					D41: =SERIESSUM(D40, 3, -1, $D$32:$F$32) + $G$32
42​	​
43​	Extrema 2​
44​	x​	22.893999​					D44: =(-E37 + SQRT(E37^2 - 4 * D37 * F37)) / (2 * D37)
45​	y​	91.175644​					D45: =SERIESSUM(D44, 3, -1, $D$32:$F$32) + $G$32

 

[jondavis1987]

Thank you for all the details. I have made every bit of that work except the linest function for the zero exponent. When i manually type in the -624 everything else generates correctly. Can you help me out just a little bit more please.

 

[jondavis1987]

Not sure if that was clear. The only thing in this i can't seem to generate is G32. I can't seem to make the formula work there.

 

[shg]

Select all four cells, paste the formula in the formula bar (sans curly braces), press and hold the Ctrl and Shift keys, then press Enter.