Can an active page be deactivated?

[Russk68]

Hi all!
In a worksheet where there are several pages active in Page Break View, is it possible to deactivate any of them even though there is information on them?

Thank you!

Russ

 

[bobsan42]

Select the area you want to have printed and use Set Print Area in Page Layout tab.
The other option is to use the blue borders in Page break preview to surround the printed area needed. One restriction is the the Print Area must consist of contiguous areas and be rectangular.

The other way to skip unneeded pages is to type the numbers of the ones to be printed in the print dialog.

 

[Russk68]

Hi Bobsan
I should have been more specific.
I want to automate the process for pages to be deactivated. Or even rows.
For an example: If A30="Deactivate" then anything below row 30 will not be printed.

Thanks!

 

[bobsan42]

try this:

Sub Deactivator()
    On Error Resume Next
    Const Str1 = "Deactivate"
    Dim strPA As String
    Dim rng As Range, rngPA As Range
    With ActiveSheet
        strPA = .PageSetup.PrintArea
        If strPA = "" Then
            If vbYes = MsgBox("No Print Area is defined. Set it to UsedRange?", vbYesNo) Then
                strPA = .UsedRange.Address
                .PageSetup.PrintArea = strPA
            Else
                GoTo EP
            End If
        End If
        Set rngPA = .Range(strPA)
        Set rng = .Range("A:A").Find(Str1)
        If rng Is Nothing Then MsgBox "No " & Str1 & " lines found.": GoTo EP
        If rng.Row <= rngPA.Row Then
            .PageSetup.PrintArea = ""
            MsgBox "Print Area is cleared."
            GoTo EP
        End If
        Set rngPA = rngPA.Resize(rng.Row - rngPA.Row)
        .PageSetup.PrintArea = rngPA.Address
    End With
EP:
    Set rng = Nothing
    Set rngPA = Nothing
End Sub

untested

 

[bobsan42]

Of course this can be made to loop through all sheets of the workbook.
But needs some small adjustments. First see if this does what you need the way you need it.

 

[Russk68]

This is great!
thank you very much!