Function that can remove any characters before a first number in a string

[tongcy]

How to write a function that can remove any characters before a first number in a string ? For instances,

Serial1/1 will become 1/1
GIGE0/1/7:1 will become 0/1/7:1
Fast1/7/LT will become 1/7/LT

 

[Rick Rothstein]

How to write a function that can remove any characters before a first number in a string ? For instances,

Serial1/1 will become 1/1
GIGE0/1/7:1 will become 0/1/7:1
Fast1/7/LT will become 1/7/LT

Give this formula a try...

=MID(A1,MIN(FIND({0,1,2,3,4,5,6,7,8,9},A1&"0123456789")),99)

 

[Aladin Akyurek]

How to write a function that can remove any characters before a first number in a string ? For instances,

Serial1/1 will become 1/1
GIGE0/1/7:1 will become 0/1/7:1
Fast1/7/LT will become 1/7/LT

B2, copied down:

=REPLACE($A2,1,MIN(FIND({0,1,2,3,4,5,6,7,8,9},$A2&"0123456789"))-1,"")

 

[tongcy]

Thanks !!!!!!!!

 

[tongcy]

B2, copied down:

=REPLACE($A2,1,MIN(FIND({0,1,2,3,4,5,6,7,8,9},$A2&"0123456789"))-1,"")

How to enhance this function to exclude remove any characters before a first number in a string and any characters after . or : ? for instance:

GigabitEthernet0/3.210 --> 0/3
Serial6/2:0.100 --> 6/2
Serial6/6:0 --> 6/6

 

[Aladin Akyurek]

How to enhance this function to exclude remove any characters before a first number in a string and any characters after . or : ? for instance:

GigabitEthernet0/3.210 --> 0/3
Serial6/2:0.100 --> 6/2
Serial6/6:0 --> 6/6

Try...

B2, copied down:

=REPLACE(LEFT(A2,MIN(FIND({".",":"},A2&".:"))-1),1,
  MIN(FIND({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))-1,"")