HELP: Read-Only Spreadsheet from Google Drive

[beddy2]

So I have a spreadsheet on Google Drive that me and other people use for our employees. Every week we send out the spreadsheet to the employees for them to see. However, it does not help them because the spreadsheet is changing constantly.

I need for them to be able to view the spreadsheet (or a version of the spreadsheet) with the current information whenever they want.

However, I do not want them to have access to be able to edit the spreadsheet. (So I guess "Locked" or "Read-Only"?)


How do I go about accomplishing this?


Thanks in advance

 

[Truiz]

Hope this helps,

https://support.google.com/docs/answer/144687?hl=en

Is that what you ehre looking for?

 

[beddy2]

Hope this helps,

https://support.google.com/docs/answer/144687?hl=en

Is that what you ehre looking for?

Yes it does. However, let me rephrase (based on new information I received)... I need information pulled from multiple sheets in my google drive to appear in a single sheet automatically. Is this possible??


For example:

Spreadsheet "C" will have a column with information that equals data in Spreadsheet "A" and Spreadsheet "B"

 

[Truiz]

I'm not sure if it would be possible on Google Docs but if it was excel here is a macro that can get the job done

Option Explicit

Sub CombineData()
'--combines data from all sheets
'  assumes all sheets have exact same header fields as the
'    first sheet; however the fields may be different order.
'--combines using copy-paste. could be modified to pasteValues only


 Dim lNdxSheet As Long, lNextRow As Long, lDestCol As Long
 Dim lColCount As Long, lRowCount As Long
 Dim rHeaders As Range
 Dim sHeader As String
 Dim vMatch As Variant, vHeaders As Variant
 Dim wksCombined As Worksheet


 With Application
   .ScreenUpdating = False
   .DisplayAlerts = False
 End With


 '--add new sheet for results
 Set wksCombined = Worksheets.Add(Before:=Worksheets(1))


 '--optional: delete existing sheet "Combined"
 On Error Resume Next
 Sheets("Combined").Delete
 On Error GoTo 0


 With wksCombined
   .Name = "Combined"
   '--copy headers that will be used in destination sheet
   Set rHeaders = Sheets(2).Range("A1").CurrentRegion.Resize(1)
   rHeaders.Copy Destination:=.Range("A1")
 End With
 '--read headers into array
 vHeaders = rHeaders.Value
 lColCount = UBound(vHeaders, 2)
 lNextRow = 2


 For lNdxSheet = 2 To Sheets.Count
   '--count databody rows of continguous dataset at A1
   lRowCount = Sheets(lNdxSheet).Range("A1").CurrentRegion.Rows.Count - 1
   If lRowCount > 0 Then
      For lDestCol = 1 To lColCount
         sHeader = vHeaders(1, lDestCol)
         '--search entire first col in case field is rSourceData
         vMatch = Application.Match(sHeader, Sheets(lNdxSheet).Range("1:1"), 0)


         If IsError(vMatch) Then
            MsgBox "Header: """ & sHeader & """ not found on sheet: """ _
               & Sheets(lNdxSheet).Name
            GoTo ExitProc
         End If
         With Sheets(lNdxSheet)
         '--copy-paste this field under matching field in combined
           .Cells(2, CLng(vMatch)).Resize(lRowCount).Copy
           '  Option 1: paste values only
           wksCombined.Cells(lNextRow, lDestCol).PasteSpecial (xlPasteValues)


           '  Option 2: paste all including formats and formulas
           '  wksCombined.Cells(lNextRow, lDestCol).PasteSpecial (xlPasteAll)  
        End With
      Next lDestCol
      lNextRow = lNextRow + lRowCount
   End If ' lRowCount > 0


 Next lNdxSheet
ExitProc:
 With Application
   .ScreenUpdating = True
   .DisplayAlerts = True
 End With


End Sub

as you can see there are 2 options one for copying the info as it is and the other one to paste the values only you need to delete the on you are not using