Hide rows across multiple worksheets based on cell value

[Sylvia C]

Hi. I would like to hide rows across multiple worksheets based on cell value. I have a VBA code that works on individual sheets in my workbook, but cannot figure out the code to apply it to multiple (13 and counting) worksheets without clicking run 13 times. I have looked through a lot of threads and tried to change the data to work for my situation, but cannot figure it out. (I have a separate code to unhide all rows with 1 click. Not sure if there's a way to make unhidden cells the default). Any help would be appreciated. Here is the code I currently have:

Sub HideRows()
Application.ScreenUpdating = False
Application.Calculation = xlManual

For Each c In Range("B8:B26")
If c.Value = 0 And c.Value <> "" Then Rows(c.Row).Hidden = True
Next

Application.Calculation = xlAutomatic
Application.ScreenUpdating = True
End Sub

 

[alansidman]

Add a loop to cycle through each worksheet

Sub HideRows()
Application.ScreenUpdating = False
Application.Calculation = xlManual
Dim ws As Worksheet
For Each ws In Worksheets
For Each c In Range("B8:B26")
If c.Value = 0 And c.Value <> "" Then Rows(c.Row).Hidden = True
Next c
Next ws


Application.Calculation = xlAutomatic
Application.ScreenUpdating = True
End Sub

 

[Sylvia C]

Thanks Alan. This still only works on the first worksheet. Any other suggestion?

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub HideRows()
   Dim c As Range
   Dim Ws As Worksheet
Application.ScreenUpdating = False
Application.Calculation = xlManual
   For Each Ws In Worksheets
      For Each c In Ws.Range("B8:B26")
         If c.Value = 0 And c.Value <> "" Then Ws.Rows(c.Row).Hidden = True
      Next
   Next Ws
Application.Calculation = xlAutomatic
Application.ScreenUpdating = True
End Sub

 

[Sylvia C]

That works great! Thank you so much

 

[Fluff]

Glad we could help & thanks for the feedback