Most common price associated with a product

[joshbjames]

This is similar to a question I have asked before. Basically, I have a list of products and the product number repeats on a new row for every price variance we have sold it for. I would like to find the price we have sold it for most frequently.

Variables to account for would be:
1 - It has only been sold at one price. (Return that value).
2 - Two different prices occur the exact same amount of times. (Return the lowest of the 2 prices).
3 - No particular price occurred more than another (Return the lowest price).

Here is some sample data with as many scenarios I could think of and the result I'd like.

Product Number	Price	Most Common
1234	2	2
1234	2	2
1234	1	2
5678	3	3
9012	4	4
9012	5	4
9012	4	4
9012	5	4
9012	3	4
3456	2	2
3456	3	2
3456	4	2
7890	5	5
7890	6	5

<tbody>
</tbody>

 

[Aladin Akyurek]

Care to state per record which of the rules (Rule-1, Rule-2, and Rule-3) applies (in order to determine "most common" price?

 

[joshbjames]

1234 - One price occurs most often, return that price.
5678 - Only one price exists, return that price.
9012 - The two most frequent prices occur the same amount of times, return the lower of the two.
3456 & 7890 - All the prices are different, return the lowest.

 

[Aladin Akyurek]

1234 - One price occurs most often, return that price.
5678 - Only one price exists, return that price.
9012 - The two most frequent prices occur the same amount of times, return the lower of the two.
3456 & 7890 - All the prices are different, return the lowest.

Thanks. The following seems to cover above rules. It needs more testing though...

In C2 control+shift+enter, not just enter, and copy down:

=IF(COUNT(MODE.MULT(IF($A$2:$A$15=$A2,$B$2:$B$15)))>1,MIN(MODE.MULT(IF($A$2:$A$15=$A2,$B$2:$B$15))),IFERROR(MODE(IF($A$2:$A$15=$A2,$B$2:$B$15)),MIN(IF($A$2:$A$15=$A2,$B$2:$B$15))))

 

[joshbjames]

Thanks, I will try this first thing in the morning and let you know! I tend to explain things in the most complicated way.

The basic idea is - Find the most frequent price. If nothing is more frequent return the lowest option. If two or more values tie for most frequent return the lowest (hopefully, that clarifies things).

 

[markmzz]

The basic idea is - Find the most frequent price. If nothing is more frequent return the lowest option. If two or more values tie for most frequent return the lowest (hopefully, that clarifies things).

Hi!

Try the Array Formula below too:

In C2 and copy down - use Ctrl+Shift+Enter to enter the formula

=IFERROR(MIN(MODE.MULT(IF($A$2:$A$15=A2,$B$2:$B$15))),MIN(IF($A$2:$A$15=A2,$B$2:$B$15)))

	A	B	C	D
1	Product Number	Price	Most Common
2	1234	2	2
3	1234	2	2
4	1234	1	2
5	5678	3	3
6	9012	4	4
7	9012	5	4
8	9012	4	4
9	9012	5	4
10	9012	3	4
11	3456	2	2
12	3456	3	2
13	3456	4	2
14	7890	5	5
15	7890	6	5
16
***	***************	******	**************	**

<tbody>
</tbody>

Markmzz

 

[joshbjames]

Thank you both so much! These were both helpful. You all helped me solve a problem that has been plaguing us at work for a very long time.