Need help with a SUMPRODUCT formula

MailmanClaims

New Member
Joined
Aug 29, 2018
Messages
2
Hello. I have been using multiple SUM(COUNTIFS( added together to search ranges across several columns that match certain terms. I would like to use SUMPRODUCT instead as it is more clean and flexible. Unfortunately I cannot get the SUMPRODUCT to work. Please have a look at my two formulas and tell me where I might be going wrong with my SUMPRODUCT.

Note that I am using named ranges (VCCs, VType, VDmg, VStatus) that refer to a column in another sheet of about 1500 items. All ranges are the same ('Sheet1'!B2:B1500, 'Sheet1'!C2:C1500, and so on).

The COUNTIFS formula I'm using (does not have the line breaks in excel, of course) is:

=SUM(COUNTIFS(VCCs,{"Name1","Name2"},VType,"GL",VDmg,{"BI";"BIPD"},VStatus,"Open"))
+SUM(COUNTIFS(VCCs,{"Name1","Name2"},VType,"GL",VDmg,{"BI";"BIPD"},VStatus,"ReOpen"))
+SUM(COUNTIFS(VCCs,{"Name1","Name2"},VType,"GL",VDmg,{"BI";"BIPD"},VStatus,"Subrogation"))


returns a total of 3, which is accurate.


The SUMPRODUCT formula (again, without the line breaks) is:


=SUMPRODUCT(ISNUMBER(MATCH(VCCs,{"Name1","Name2"},0))
*ISNUMBER(MATCH(VType,"GL",0))
*ISNUMBER(MATCH(VDmg,{"BI","BIPD"},0))
*ISNUMBER(MATCH(VStatus,{"Open","ReOpen","Subrogation"},0)))


but returns a total of 0.

Based on my understanding of these formulas they should be spitting out the same result, but they are not. Could anyone explain why that might be the case and suggest a fix?

Thank you very much.
 
Last edited by a moderator:

Some videos you may like

Excel Facts

Why does 9 mean SUM in SUBTOTAL?
It is because Sum is the 9th alphabetically in Average, Count, CountA, Max, Min, Product, StDev.S, StDev.P, Sum, VAR.S, VAR.P.

MailmanClaims

New Member
Joined
Aug 29, 2018
Messages
2
Bumping my thread as it has been almost a month with no reply. Hopefully someone will be able to help!
 

Dave Patton

Well-known Member
Joined
Feb 15, 2002
Messages
4,037
Office Version
2010
Platform
Windows
try either of

=SUMPRODUCT(--(ISNUMBER(MATCH(VCCs,{"Name1","Name2"},0))),--(VType="GL"),--(ISNUMBER(MATCH(VDmg,{"BI","BIPD"},0))),--(ISNUMBER(MATCH(Vstatus,{"Open","ReOpen","Subrogation"},0))))

=SUMPRODUCT(ISNUMBER(MATCH(VCCs,{"Name1","Name2"},0))*(VType="GL")*ISNUMBER(MATCH(VDmg,{"BI","BIPD"},0))*ISNUMBER(MATCH(Vstatus,{"Open","ReOpen","Subrogation"},0)))
 

Watch MrExcel Video

Forum statistics

Threads
1,099,549
Messages
5,469,378
Members
406,647
Latest member
ssinovec

This Week's Hot Topics

Top