Parse spreadsheet into separate tabs in same spreadsheet

[JSH720]

I have see the answer to this here, but cannot find it now that I need it.

I need to take a very large spreadsheet and make separate tabs in the same spreadsheet based, in this case, on a combination the county and state columns. (each County/State will have a separate tab in the spreadsheet). The county and the state are separate columns.
The large spreadsheet will remain intact.

Any help is appreciated!

 

[Fluff]

Which columns are the county & state in?

 

[JSH720]

It various between spreadsheets, but we can use f and g for this and I can change it as needed.

Thanks.

 

[Fluff]

How about

Sub JSH720()
   Dim Ws As Worksheet
   Dim Cl As Range
   Dim Ky As Variant
   
   Set Ws = Sheets("[COLOR=#ff0000]Sheet1[/COLOR]")
   If Ws.AutoFilterMode Then Ws.AutoFilterMode = False
   With CreateObject("scripting.dictionary")
      For Each Cl In Ws.Range("F2", Ws.Range("F" & Rows.Count).End(xlUp))
         .Item(Cl.Value & "|" & Cl.Offset(, 1).Value) = Empty
      Next Cl
      For Each Ky In .Keys
         Sheets.Add(, Sheets(Sheets.Count)).Name = Left(Ky, 30)
         Ws.Range("A1:G1").AutoFilter 6, Split(Ky, "|")(0)
         Ws.Range("A1:G1").AutoFilter 7, Split(Ky, "|")(1)
         Ws.AutoFilter.Range.EntireRow.Copy Range("A1")
      Next Ky
   End With
End Sub

Change sheet name in red to suit

 

[Fluff]

Couple of mods to the above code

Sub JSH720()
   Dim Ws As Worksheet
   Dim Cl As Range
   Dim Ky As Variant
   
   [COLOR=#ff0000]Application.ScreenUpdating = False[/COLOR]
   Set Ws = Sheets("Sheet1")
   If Ws.AutoFilterMode Then Ws.AutoFilterMode = False
   With CreateObject("scripting.dictionary")
      [COLOR=#ff0000].CompareMode = 1[/COLOR]
      For Each Cl In Ws.Range("F2", Ws.Range("F" & Rows.Count).End(xlUp))
         .Item(Cl.Value & "|" & Cl.Offset(, 1).Value) = Empty
      Next Cl
      For Each Ky In .Keys
         Sheets.Add(, Sheets(Sheets.Count)).Name = Left(Ky, 30)
         Ws.Range("A1:G1").AutoFilter 6, Split(Ky, "|")(0)
         Ws.Range("A1:G1").AutoFilter 7, Split(Ky, "|")(1)
         Ws.AutoFilter.Range.EntireRow.Copy Range("A1")
      Next Ky
   End With
   [COLOR=#ff0000]Ws.AutoFilterMode = False[/COLOR]
End Sub

 

[JSH720]

Thank you. works like a charm.

 

[Fluff]

You're welcome & thanks for the feedback