VBA: Change Footer Logo Image (Right Section)

[unknownymous]

Hi Guys,

I have this task which I need to update the logo image which is usually do the same for 8 tabs. I tried highlighting all the tabs but in some way it affects the formatting of the macro enabled worksheet I'm using.

8 Tabs : Results, Summary, Students, Room, Subjects, Trainor, Schedule & Others
I'm thinking of option to select tabs then update the footer logo image (on the right section) afterwards.


Any help will be much appreciated.

 

[John_w]

Have you tried recording a macro whilst you insert and then change the footer for one of the sheets? This will show the VBA footer syntax and properties.

Try this macro, changing the image file as required:

Public Sub Change_Image_In_Footers()

    Dim wsName As Variant
    Dim imageFile As String
    
    imageFile = "C:\path\to\image.jpg"
    
    For Each wsName In Array("Results", "Summary", "Students", "Room", "Subjects", "Trainer", "Schedule", "Others")
        With ThisWorkbook.Worksheets(wsName).PageSetup
            .RightFooter = "&G"
            .RightFooterPicture.Filename = imageFile
        End With
    Next
    
End Sub

 

[unknownymous]

Thank you

 

[unknownymous]

One thing, what if one tab doesn't exist and just want to skip or ignore the error? Or to be safe, can I just select the tabs and run the macro? Thanks again.

 

[John_w]

Run this on the selected tabs (grouped sheets).

Public Sub Change_Image_In_Footers2()

    Dim ws As Worksheet
    Dim imageFile As String
    
    imageFile = "C:\path\to\image.jpg"
    
    For Each ws In ActiveWindow.SelectedSheets
        With ws.PageSetup
            .RightFooter = "&G"
            .RightFooterPicture.Filename = imageFile
        End With
    Next
    
End Sub