VBA for Macro Button

[nathanthomson11]

I'm not overly knowledgeable when it comes to VBA so I'm hoping someone can write me a quick VBA for this purpose. I have a long list of items in a tracking file, each line-item has a barcode in column D and a macro button beside each barcode in column E. I need a VBA code so if I click on the macro button in column E, it will print the barcode located to the left in column D.

The challenge is that there are hundreds of barcodes, each with it's own macro so the follow coding I have only works for 1 unless I make a module for each.

Sub PrintSomeCells()
Range ("D360").PrintOut
End Sub

Thank you in advance!

 

[Fluff]

What sort of buttons are you using?
ActiveX or Forms Control?

 

[nathanthomson11]

What sort of buttons are you using?
ActiveX or Forms Control?

Foms Contro

 

[Fluff]

In that case try assigning this to each button

Sub nathanthomson11()
   Dim Shp As Shape
   
   Set Shp = ActiveSheet.Shapes(Application.Caller)
   Shp.TopLeftCell.Offset(, -1).PrintOut
End Sub

You will need to make sure that the top left corner of each button is in col E

 

[nathanthomson11]

This worked great - thank you! Is there any way to add to this VBA to automatically change the printer to "ZDesigner GX420t" ??

In that case try assigning this to each button

Sub nathanthomson11()
   Dim Shp As Shape
   
   Set Shp = ActiveSheet.Shapes(Application.Caller)
   Shp.TopLeftCell.Offset(, -1).PrintOut
End Sub

You will need to make sure that the top left corner of each button is in col E

 

[Fluff]

Change A1 to an unused cell & run this

Sub Chk()
Range("A1").Value = ActivePrinter
End Sub

What does it output?

 

[nathanthomson11]

It displays the following in A1:

ZDesigner GX420t on Ne00:

Change A1 to an unused cell & run this

Sub Chk()
Range("A1").Value = ActivePrinter
End Sub

What does it output?

 

[Fluff]

In that case try

Sub nathanthomson11()
   Dim Shp As Shape
   Dim Prntr As String
   
   Prntr = ActivePrinter
   ActivePrinter = "ZDesigner GX420t on Ne00:"
   Set Shp = ActiveSheet.Shapes(Application.Caller)
   Shp.TopLeftCell.Offset(, -1).PrintOut
   ActivePrinter = Prntr
End Sub