Macro for writing to specific Excel spreadsheets

[KhallP]

I want to make a macro that just inserts values in cells where the name of the worksheets is different from "Potable C1", "Potable C2", "Potable C3.1", "Potable C3.2", the code is not working because it is writing in all spreadsheets, can someone help me?

Dim sh As Worksheet
Dim counter As Integer, ws As Integer

Public Sub WriteValues()

    ws = ActiveWorkbook.Sheets.Count

    For counter = 1 To ws
        Worksheets(counter).Select
        Set sh = ActiveSheet
    
        If sh.Name <> "Potável C1" Or sh.Name <> "Potável C2" Or sh.Name <> "Potável C3.1" Or sh.Name <> "Potável C3.2" Then
    
                Range("AC12").Select
                If ActiveCell.Value = "" Then
                    With ActiveSheet.Range("AC12:AE12")
                        .Font.Bold = True
                        .Value = Array("Date", "Time", "Value")
                        .HorizontalAlignment = xlRight
                    End With
            
                Else
                End If

                Range("AC13").Select
                If ActiveCell.Value = "" Then
                    ActiveCell.Value = Range("U13").Value
                    Range("AE13").Value = WorksheetFunction.Sum(Range("W13:W108"))
                    Range("AF13").Value = "kWh"
            
                Else
                End If
        
        Else
        End If
    
    Next counter
End Sub

 

[Peter_SSs]

Is this what you mean?

If sh.Name <> "Potável C1" Or sh.Name <> "Potável C2" Or sh.Name <> "Potável C3.1" Or sh.Name <> "Potável C3.2" Then
If sh.Name <> "Potável C1" And sh.Name <> "Potável C2" And sh.Name <> "Potável C3.1" And sh.Name <> "Potável C3.2" Then

BTW, there should be no need to activate each sheet to do this task.

 

[KhallP]

Is this what you mean?

If sh.Name <> "Potável C1" Or sh.Name <> "Potável C2" Or sh.Name <> "Potável C3.1" Or sh.Name <> "Potável C3.2" Then
If sh.Name <> "Potável C1" And sh.Name <> "Potável C2" And sh.Name <> "Potável C3.1" And sh.Name <> "Potável C3.2" Then

BTW, there should be no need to activate each sheet to do this task.

Thank you very much for your answer, corrected my error, but I need to put "Worksheets (counter) .Select" yes, otherwise it doesn't work

 

[Peter_SSs]

but I need to put "Worksheets (counter) .Select" yes, otherwise it doesn't work

No. You rarely need to select anything in vba to work with it and selecting slows your code.
Here is one way to do what you were doing without selecting any sheets or any cells.

Sub WriteValues_WithoutSelect()
  Dim ws As Worksheet
  
  For Each ws In ActiveWorkbook.Worksheets
    With ws
      If .Name <> "Potável C1" And .Name <> "Potável C2" And .Name <> "Potável C3.1" And .Name <> "Potável C3.2" Then
        If .Range("AC12").Value = "" Then
          With .Range("AC12:AE12")
            .Font.Bold = True
            .Value = Array("Date", "Time", "Value")
            .HorizontalAlignment = xlRight
          End With
        End If
        If .Range("AC13").Value = "" Then
          .Range("AC13").Value = .Range("U13").Value
          .Range("AE13").Value = WorksheetFunction.Sum(.Range("W13:W108"))
          .Range("AF13").Value = "kWh"
        End If
      End If
    End With
  Next ws
End Sub