VBA Loop. Putting today's date into cell if certain conditions are met

[Magoosball]

I am trying to write a script that will do the following:

• Check to see if column N is empty. If column N isn't empty then go onto the next row. If it is empty then check to see if Column F contains the word "January". If Column F contains that word then put today's date into Column N.
• Check to see if column O is empty. If column O isn't empty then go onto the next row. If it is empty then check to see if Column F contains the word "February" OR "March". If Column F contains either of those words then put today's date into Column O.
• Check to see if column P is empty. If column P isn't empty then go onto the next row. If it is empty then check to see if Column F contains the word "April" OR "May" OR "June". If Column F contains any of those words then put today's date into Column P.

This should continue until the last row of the worksheet as dictated by no date in column A.
This is going to be ran daily to put today's date into Column N, O, P. This is why it is important to check to see if that column is empty before continuing.

 

[NoSparks]

assuming column A is only dates and row 1 is headers
try this, adjust sheet name to suit

Sub testing()

    Dim i As Long

With Sheets("Sheet1")
    For i = 2 To .Cells(Rows.Count, "A").End(xlUp).Row
        If IsEmpty(.Cells(i, "N")) Then
            If InStr(.Cells(i, "F"), "January") > 0 Then .Cells(i, "N").Value = Date
        End If
        
        If IsEmpty(.Cells(i, "O")) Then
            If InStr(.Cells(i, "F"), "February") > 0 Or InStr(.Cells(i, "F"), "March") > 0 Then .Cells(i, "O").Value = Date
        End If
        
        If IsEmpty(.Cells(i, "P")) Then
            If InStr(.Cells(i, "F"), "April") > 0 Or InStr(.Cells(i, "F"), "May") > 0 Or InStr(.Cells(i, "F"), "June") > 0 Then .Cells(i, "P").Value = Date
        End If
    Next i
End With
End Sub